大智慧KINGWA 扩展续：在K线显示你的买卖操作

阅读作者：股海网时间 2017-11-19 大智慧软件

作为股民盘后一个工作就是对自己的操作进行总结（或对别人的操作进行观摩），提高自己，需要在K线上显示自己的买卖情况。大智慧里面有个投资管理文件，可以记录自己的操作，KINGWA提供一个函数读取这个文件并显示在相应的K线上，当然也可以在动态显示牌上进行汇总，看自己在那些股票中赚钱了，为啥赚？
格式:“kingwa@Trade”(帐号，操作类型)
    1、参数1：帐号
   其中帐号是你显示哪个投资管理文件(大智慧显示的投资者）（文件在大智慧的\USERDATA\SELF目录下），由于大智慧不能传字符串，只能用一个数字传进去，需要在kingwa.ini 文件中配置帐号对应的文件名，在你的kingwa.ini 目录中增加下列内容（熟悉kingwa的人知道这个配置文件还可以配置其他内容）
        [投资账户]
             8=my17.INV
    这个8对应文件my17.INV投资文件
   2、参数2：操作类型
          分别定于为：操作类型 1 - 卖价 2 卖股数 3 买价 4 买股数
举例如下：
账号:=8*(c>0);
if (账号>=0) then
   begin
    买股:="kingwa@Trade"(账号,4);
    买价:="kingwa@Trade"(账号,3);
    买额:=买股*买价;
    DRAWICON(买股>0 ,max(min(买价,h),l),7,1),LAYER0,PRECIS0;
    DRAWFLAGTEXT(买股>0 ,买价,'开盘涨幅:'+numtostrn(o/ref(c,1)*100-100,1)+'% 买点涨幅:'+numtostrn(买价/ref(c,1)*100-100,1)+'%'),COLORRED;
    DRAWFLAGTEXT(买股>0,买价,'买入:'+NUMTOSTRN(买股,0)+'股，价格：'+NUMTOSTRN(买价,2)+' 金额：'+NUMTOSTRN(买额,0)),COLORGREEN;
    卖股:="kingwa@Trade"(账号,2);
    卖价:="kingwa@Trade"(账号,1);
    卖额:=卖股*卖价;
    DRAWICON( 卖股<>0,max(min(卖价,h),l),8,-12),LAYER0,PRECIS0;
    DRAWFLAGTEXT(卖股>0,卖价,'卖出:'+NUMTOSTRN(卖股,0)+'股，价格：'+NUMTOSTRN(卖价,2)+' 金额：'+NUMTOSTRN(卖额,0)),COLORGREEN;
    drawline(买股>0,max(min(买价,h),l),卖股<>0 ,max(min(卖价,h),l),0),coloryellow;
    end;

把这段代码放入你的主图公式中就可以显示你相关内容中了。
喜欢就玩玩。
KINGWA.zip (303.7 KB)

后话：当然你可以把自己的操作记录录入投资管理中（我是用另外的工具交易将记录导入进去的），这是很多年前的设计，如果我现在设计，也许就直接读execl交易记录文件了，或者直接从交易软件中读数据了。。。）

例子2：操作统计

{ opn 1 - 卖价 2 卖股数 3 买价 4 买股数 }
input:起始时间(120101,110101,190101,1);

起始时间:=150101;
账号:="投资账号.账号#day";
有效期:=date-1000000>起始时间;
买股:if(有效期,"kingwa@Trade"(账号,4),0),PRECIS0,LINETHICK0;
买股0:"kingwa@Trade"(0,4);
买价:if(有效期,"kingwa@Trade"(账号,3),0),PRECIS0,LINETHICK0;
买额:=买股*买价;
DRAWICON(买股>0 ,min(买价,h),7),LAYER0;
卖股:if(有效期,"kingwa@Trade"(账号,2),0),PRECIS0,LINETHICK0;
卖价:if(有效期,"kingwa@Trade"(账号,1),0),PRECIS0,LINETHICK0;
卖额:=卖股*卖价;
DRAWICON( 卖股>0,min(卖价,h),8),LAYER0;
num:=买股-卖股;
je:=卖额-买额;

天数0:=barssince(date-1000000>=起始时间 );
sumsk:=sum(num,天数0);{,PRECIS0,LINETHICK0;}
库存:sum(买股-卖股,0),PRECIS0,LINETHICK0;
投资金额:=sum(je,天数0);
总盈利:库存*c+sum(卖额-买额,0),PRECIS0,LINETHICK0,COLORRED;
成本:=投资金额/库存;

最新操作:BARSLAST(买股>0 or 卖股>0),LINETHICK0,PRECIS0;
最近买入:=BARSLAST(cross(库存,50));
最新卖出:=BARSLAST(cross(50,库存));
最近买价:ref(买价,最近买入),PRECIS2,linethick0;
最近卖价:ref(卖价,最新卖出),PRECIS2,linethick0;
持股天数:if(库存<50,最近买入-最新卖出,最近买入),PRECIS0,linethick0;
最新时间:ref(date,最新操作)-1000000,linethick0,precis0;
{
m1:sum(卖额,最近买入+1),PRECIS0,LINETHICK0;
m2:sum(买额,最近买入+1),PRECIS0,LINETHICK0;
}
盈利比例:(sum(卖额,最近买入+1)-sum(买额,最近买入+1)+sum(num,最近买入+1)*C)/sum(买额,最近买入+1)*100,PRECIS1,linethick0;
n:=barslast(cross(库存,0))+1;
均价:sum(买额,n)/sum(买股,n),linethick0;
DRAWFLAGTEXT(买股>0,买价,'买入:'+NUMTOSTRN(买股,0)+'股，价格：'+NUMTOSTRN(买价,2)+' 金额：'+NUMTOSTRN(买额,0)),COLORRED;
DRAWFLAGTEXT(买股>0,买价,'开盘涨幅:'+numtostrn(o/ref(c,1)*100-100,1)+'% 买点涨幅:'+numtostrn(买价/ref(c,1)*100-100,1)+'%'),COLORRED;
DRAWFLAGTEXT(卖股>0,卖价,'卖出:'+NUMTOSTRN(卖股,0)+'股，价格：'+NUMTOSTRN(卖价,2)+' 金额：'+NUMTOSTRN(卖额,0)),COLORGREEN;
DRAWFLAGTEXT(卖股>0,卖价,'盈利:'+NUMTOSTRN((卖价/均价-1)*100,1)+'% 金额：'+NUMTOSTRN((卖价-均价)*卖股,0)),COLORGREEN;
DRAWFLAGTEXT(卖股>0,卖价,'距高点:'+NUMTOSTRN((卖价/H-1)*100,1)+'% '),COLORGREEN;
操作次数:count(卖股>0 or 买股>0,0) /2,PRECIS0,linethick0;
买点涨幅:最近买价/ref(c,最近买入+1)*100-100,LINETHICK0;
持股:if(库存<0,-库存,库存),LINETHICK0;